Cara Backup Mikrotik Otomatis Online & Local

Suatu saat mikrotik anda pasti akan rusak, baik rusak alami atau dirusak orang/dihack.

Sebelum hal itu terjadi, backup perlu dilakukan agar anda tidak kehilangan data/settingan mikrotik.

Anda bisa melakukan backup mikrotik otomatis ke email, microSD, flashdisk,SSD secara berkala.

Daftar Isi :

Teknik Pencadangan Settingan Mikrotik

Untuk melakukan backup/pencadangan settingan/konfigurasi mikrotik anda bisa memanfaatkan fitur yang terlah disediakan sesuai kebutuhan.

File hasil backup bisa anda download dan simpan ke komputer anda.

Cukup masuk ke menu Files > klik kanan pada file hasil backup lalu pilih download.

Menggunakan Fitur Backup

Fitur backup bisa diakses dengan perintah > system backup save dari terminal atau dengan klik tombol backup pada menu files.

Fitur ini membackup seluruh settingan/konfigurasi mikrotik anda secara otomatis ketika perintah dijalankan.

cara backup settigan mikrotik manual — backup konfigurasi mikrotik cara manual

FIle hasil backup dengan extensi *.backup tidak dapat diedit sehingga file backup hanya bisa direstore ke mikrotik dengan tipe/model yang sama.

Jika anda coba restore ke mikrotik tipe lain settingan akan berantakan , bahkan ada beberapa kasus mikrotik berjalan tidak normal.

Menggunakan fitur Export

Fitur Export memberikan anda kebebasan saat membackup settingan mikrotik.

Anda bisa meng export settingan tertentu kedalam sebuah file text yang bis anda edit dengan extensi *.rsc

File hasil export bisa anda edit dan import ke mikrotik yang beda tipe atau jenis.

cara backup settingan mikrotik dengan cara export — cara export settingan mikrotik manual

Fitur export hanya bisa dipakai dari console/terminal menggunakan perintah > xxx export file=”namafile”

dimana xxx adalah path yang akan diexport.

Jika ingin mengexport seluruh settingan maka gunakan path / sehingga perintah nya adalah > /export file=”namafile”

Mendownload File Hasil Backup

File hasil backup dengan nama *.backup atau *.rsc bisa anda download ke komputer/laptop anda.

Simpan file ini baik2-baik

Cara download file hasil backup mikrotik :

Klik menu file > klik kanan pada file hasil backupan > pilih download
Atau drag file langsung dari winbox ke desktop/folder komputer anda

Cara Backup Mikrotik Otomatis ke Lokal Drive

Anda bisa membackup settingan mikrotik secara otomatis ke storage internal mikrotik ataupun external.

Saya menyarankan untuk menggunakan external storage seperti MicroSD, SSD atau flashdisk jika mikrotik anda punya port USB ataupun microSD.

Hindari backup otomatis ke internal storage karena bisa bikin mikrotik hang jika kepenuhan.

Menyiapkan Storage

Wajib gunakan media penyimpan external, jangan gunakan storage sistem.

Karena jika storage system sampai full, nanti mikrotik bisa eror.!!!

Untuk storage external anda bisa menggunakan Flashdisk, SSD ataupun microSD.

Silahkan sesuaikan dengan port yang ada di mikrotik anda.

Colok/tancap storage yang akan anda pakai
masuk ke menu system > disk
Jika ukuran free space belum muncul/blank maka format terlebih dahulu dengan klik menu format
anda bisa ubah nama dengan klik 2x pada disk name
cek di menu Files, harusnya akan ada folder dengan nama disk yang anda baru setting tadi.

Jika ingin copot drive anda bisa gunakan menu eject.

Sampai langkah ini drive anda sudah siap dipakai untuk nampung hasil bakcup mikrotik otomatis.

Script Auto Backup & Export ke MicroSD

Agar kita tidak repot backup manual tiap hari, saya ada script yang bisa anda pakai agar mikrotik anda backup secara otomatis sesuai waktu yang anda mau.

## AUTOBACKUP MIKROTIK LOCAL v.2.0| TEMBOLOK.ID
## Support Mikrotik V7

# setting nama storage
# disk2 silahkan ganti sesuai dengan nama storage anda di mikrotik


:local storage "disk2";


:local date [/system clock get date];
:if ([:pick $date 4 5] = "-") do={:local arraybln {"01"="jan";"02"="feb";"03"="mar";"04"="apr";"05"="may";"06"="jun";"07"="jul";"08"="aug";"09"="sep";"10"="oct";"11"="nov";"12"="dec"};
:local tgl [:pick $date 8 10];
:local bulan [:pick $date 5 7];
:local tahun [:pick $date 0 4];
:local bln ($arraybln->$bulan);
:set $date ($bln."/".$tgl."/".$tahun);};
:local jam [:pick [/system clock get time] 0 2];
:local min [:pick [/system clock get time] 3 5];
:local dtk [:pick [/system clock get time] 6 8];
:local bln [:pick $date 0 3];
:local tgl [:pick $date 4 6];
:local thn [:pick $date 7 11];
log warning ("SYSTEM Export DIJALANKAN Pada : $tgl/$bln/$thn $jam:$min:$dtk");
/export  file="$storage/backup-$tgl$bln$thn_$jam_$min_$dtk"
log warning ("SYSTEM BACKUP DIJALANKAN Pada : $tgl/$bln/$thn $jam:$min:$dtk");
/system backup save dont-encrypt=yes name="$storage/backup-$tgl$bln$thn_$jam_$min_$dtk"

log warning ("PROSES BACKUP & EXPORT ke STORAGE $storage SELESAI!!");

Script autobackup mikrotik ini akan menghasilkan file export dengan extensi *.src dan file backup dengan extensi *.backup.

File akan disimpan otomatis di storage yang telah anda tentukan pada varible $storage dalam hal ini adalah disk2

Jadi pastikan nama local storage sudah sama sesuai dengan yang anda miliki.

Mengatur Jadwal Autobackup & Export Mikrotik

Pasang script dibawah ini pada scheduler (system > scheduler) dengan interval yang anda mau.

Saya seting untuk backup otomatis setiap 12jam (interval ), dimulai dari jam 00.00 (start time).

Untuk variable storage, silahkan isikan dengan nama storage yang telah anda set di langkah sebelum nya.

script backup dan export settingan mikrotik otomatis ke microSD, flashdisk dan SSD external — script autobackup mikrotik ke storage

Cara Backup Mikrotik Otomatis Online ke Email

Jika mikrotik anda tidak punya port USB /micro SD, anda tetap bisa melakukan backup otomatis ke Email.

Saya menggunakan email google/Gmail, jika anda mau pake email lain juga bisa.

Menyiapkan Akun Email

Khusus untuk gmil, anda perlu membuat app password yang nantinya akan dipakai untuk login ke SMPT server GMAIL dengan lebih aman.

Password nya akan beda dengan password email.

Tapi untuk bisa pakai fitur ini anda harus aktifkan dulu fitur authentifikasi 2 langkah Gmail anda.

membuat app password gmail untuk mikrotik — membuat password app untuk mikrotik

buka link https://myaccount.google.com/security?gar=1
pastikan verifikasi 2 langkah/2-Step Verification sudah aktif , jika belum aktifkan dulu dan ikuti prosedurnya.
klik pada app password untuk membuat password khusus yang akan kita pakai di mikrotik
copy password tersebut dan paste ke notepad agar anda tidak lupa.

Nantinya untuk username : alamat email kita, sedangkan password menggunakan app password yang telah kita buat.

Setting SMTP Email di Mikrotik

Agar mikrotik bisa mengirim email maka anda perlu memasang akun SMPT Gmail yang telah anda buat tadi ke mikrotik.

masuk ke menu tools > Email
masukan server dan port seperti gambar dibawah ini
user adalah alamat email gmail anda dan password adalah app password yang telah kita buat tadi.
klik OK untuk menyimpan.

setting email google di mikrotik — memasang SMTP Gmail di mikrotik

Khusus untuk mikrotik v.7 , bagian TLS pilih : start tls

Untuk mencoba kirim email dari mikrotik anda bisa gunakan perintah ini di terminal, ganti “to=” dengan alamat email tujuan yang valid.

/tool e-mail send [email protected] subject="test backup mikro
tik" from="TBID Router" body="ngetest"

cara test kirim email dari mikrotik menggunakan terminal console — kirim email dari mikrotik terminal

Jika berhasil maka di menu “LOG” akan muncul peringatan “SENT” seperti digambar atas.

Script Auto Backup & Export ke Email

Modifikasi script dibawah ini sesuai yang anda mau, yang paling penting dan wajib diubah adalah variable “tujuan”.

Isikan dengan email yang akan anda pakai untuk menerima hasil backup otomatis.

Script ini akan mengirimkan 2 buah file dengan extensi *.backup dan *.src

Anda tidak perlu kuatir storage penuh, karena file akan dihapus otomatis setelah email berhasil dikirim.

## AUTOBACKUP MIKROTIK ONLINE v.2.7 | Tembolok.ID 
## Fix Email Attachment String & Compile Error v6

:local tujuan "[email protected]";
:local ID "nama atau identitas unik mikrotikmu";

:local identity [/system identity get name];
:local subject "Backup Rutin Mikrotik $identity | $ID";
:local pesan "Email ini dikirim otomatis dari Mikrotik $identity berisi file .backup & export .rsc.";

# Get Time & Date
:local clock [/system clock get];
:local time ($clock->"time");
:local date ($clock->"date");

:local jam [:pick $time 0 2];
:local min [:pick $time 3 5];
:local dtk [:pick $time 6 8];

:local bln; :local tgl; :local thn;

# Format tanggal v7 berbeda dengan v6, ini deteksi otomatisnya
:if ([:pick $date 4] = "-") do={
    :local arraybln {"01"="jan";"02"="feb";"03"="mar";"04"="apr";"05"="may";"06"="jun";"07"="jul";"08"="aug";"09"="sep";"10"="oct";"11"="nov";"12"="dec"};
    :set tgl [:pick $date 8 10];
    :set bln ($arraybln->[:pick $date 5 7]);
    :set thn [:pick $date 0 4];
} else={
    :set bln [:pick $date 0 3];
    :set tgl [:pick $date 4 6];
    :set thn [:pick $date 7 11];
};

# Set Filename & Cek Versi ROS
:local namafile "$tgl_$bln_$thn_$jam_$min_$dtk";
:local namafilersc "$namafile.rsc";
:local namafilebackup "$namafile.backup";
:local rosver [:pick [/system resource get version] 0 1];

# 1. Pembuatan System Backup (.backup)
:log warning "SYSTEM Backup (.backup) DIJALANKAN Pada : $namafile";
:do {
    /system backup save name=$namafile;
    :delay 5s;
} on-error={
    :log error "Gagal membuat file .backup (Storage penuh/Error)";
}

# 2. Pembuatan Export Config (.rsc) - DYNAMIC PARSE
:log warning "SYSTEM Export (.rsc) DIJALANKAN Pada : $namafile";
:do {
    :if ($rosver = "6") do={
        :local cmd "/export file=\"$namafile\"";
        [:parse $cmd];
    } else={
        :local cmd "/export show-sensitive file=\"$namafile\"";
        [:parse $cmd];
    }
    :delay 10s;
} on-error={
    :log error "Gagal melakukan export konfigurasi (Storage penuh/Error)";
}

# 3. Proses Kirim Email
:do {
    :log warning "Mengirim email backup ke $tujuan...";
    # Menggunakan tipe data String dengan pemisah koma (tanpa spasi) yang didukung penuh v6
    /tool e-mail send to=$tujuan subject=$subject body=$pesan file="$namafilersc,$namafilebackup";
    :log warning "Menunggu email terkirim...";
    
    :local timeout 0;
    :local isDone false;

    :while ($timeout < 25 and !$isDone) do={
        :delay 3s;
        :set timeout ($timeout + 1);
        :log info "Menunggu email terkirim... $timeout";
        
        :local lastStatus [/tool e-mail get last-status];
        
        :if ($lastStatus = "succeeded") do={
            :set isDone true;
            :log info "Email backup BERHASIL terkirim.";
        } else={
            :if ($lastStatus = "failed") do={
                :set isDone true;
                :log error "Email backup GAGAL terkirim! Cek SMTP / Internet.";
            }
        }
    }
} on-error={
    :log error "Terjadi fatal error saat proses pengiriman email!";
}

# 4. Hapus Temporary Files (Selalu dieksekusi)
:delay 3s;
:do {
    # Menghapus file .rsc
    :if ([:len [/file find name=$namafilersc]] > 0) do={
        /file remove [/file find name=$namafilersc];
    }
    
    # Menghapus file .backup
    :if ([:len [/file find name=$namafilebackup]] > 0) do={
        /file remove [/file find name=$namafilebackup];
    }
    
    :log warning "Temporary backup files (.rsc & .backup) berhasil dihapus.";
} on-error={
    :log debug "File temporary tidak ditemukan atau ada error saat menghapus file.";
}

Schedul Autobackup & Export Mikrotik ke Email

Agar mikrotik anda melakukan backup otomatis dan mengirimkan ke email sesuai waktu yang anda inginkan maka perlu dibuat scheduler.

Masuk ke menu system > scheduler > klik tanda +
start time isikan dengan jam awal mulai timer berjalan
interval isikan dengan berapa lama timer hingga mengeksekusi scheduler.
pada kotak on event paste script autobackup email diatas yang telah anda modifikasi.
klik OK

script autobackup settingan mikrotik ke email — setting mikrotik backup otomatis ke email

Untuk mencoba anda bisa set interval ke 5 menit, jangan lupa langsung set interval ke yang anda mau setelah selesai mencoba/testing.

Pada contoh diatas script akan dijalankan sehari sekali (internval 1d), pada jam 2 malam (start time 02:00:00:00)

KESIMPULAN

Backup mikrotik wajib dan harus dilakukan dengan rutin untuk mengantisipasi hal yang tidak diinginkan.

Hasil backup wajib disimpah di media external, agar ketika mikrotik rusak file hasil backup bisa direstore ke mikrotik baru.

Untuk memudahkan pekerjaan backup anda bisa menggunakan script autobackup yang telah saya siapkan.

Script ini bisa membackup mikrotik otomatis ke storage local dan email yang cocok untuk semua tipa mikrotik yang anda punya.

4 pemikiran pada “Cara Backup Mikrotik Otomatis Online & Local”

Reza MA
13 April 2024 pada 9:06 am
mas bisa minta update untuk script ROS 7 yg terbaru, penamaan file backup jadi agak kacau di ros7 terbaru, akhirnya gk bisa terkirim ke email
- Arianto
  20 April 2024 pada 5:45 am
  baik.. akan segera saya update..
Edi Hermawan
14 Agustus 2022 pada 1:23 pm
sangat bermanfaat kak.
boleh kasi masukan kak, untuk yg export ke disk external, alangkah lebih baik nya jika di hapus otomatis juga yg hasil backup yg sebelum nya jika hasil yg sekarang sudah keluar
- Arianto
  18 Agustus 2022 pada 8:20 am
  silahkan dihapus kalo anda tidak memerlukan nya. sebagian orang memerlukan nya.

Komentar ditutup.